Add files from zip

tests/tests.pri

@@ -0,0 +1,71 @@
+################################################################
+# Qwt Widget Library
+# Copyright (C) 1997   Josef Wilgen
+# Copyright (C) 2002   Uwe Rathmann
+#
+# This library is free software; you can redistribute it and/or
+# modify it under the terms of the Qwt License, Version 1.0
+###################################################################
+
+QWT_ROOT = $${PWD}/..
+include( $${QWT_ROOT}/qwtconfig.pri )
+include( $${QWT_ROOT}/qwtbuild.pri )
+include( $${QWT_ROOT}/qwtfunctions.pri )
+
+QWT_OUT_ROOT = $${OUT_PWD}/../..
+
+TEMPLATE     = app
+
+INCLUDEPATH += $${QWT_ROOT}/src
+DEPENDPATH  += $${QWT_ROOT}/src
+
+INCLUDEPATH += $${QWT_ROOT}/classincludes
+DEPENDPATH  += $${QWT_ROOT}/classincludes
+
+!debug_and_release {
+
+    DESTDIR      = $${QWT_OUT_ROOT}/tests/bin
+}
+else {
+    CONFIG(debug, debug|release) {
+
+        DESTDIR      = $${QWT_OUT_ROOT}/tests/bin_debug
+    }
+    else {
+
+        DESTDIR      = $${QWT_OUT_ROOT}/tests/bin
+    }
+}
+
+
+QMAKE_RPATHDIR *= $${QWT_ROOT}/lib
+qwtAddLibrary($${QWT_OUT_ROOT}/lib, qwt)
+
+greaterThan(QT_MAJOR_VERSION, 4) {
+
+    QT += printsupport
+    QT += concurrent
+}   
+
+contains(QWT_CONFIG, QwtOpenGL ) {
+
+    QT += opengl
+}
+else {
+
+    DEFINES += QWT_NO_OPENGL
+}
+
+contains(QWT_CONFIG, QwtSvg) {
+
+    QT += svg
+}
+else {
+
+    DEFINES += QWT_NO_SVG
+}
+
+
+contains(QWT_CONFIG, QwtDll) {
+    DEFINES    += QT_DLL QWT_DLL
+}